# Gnuplot script file for plotting data in file "*.dat"
# This file is called   estilo.p

#=======================================================
#     Line wide point size and font aspects
#=======================================================
#
#     Specify the line wide and dot size

  linw=1.6
  poin=1
  fsize=14
#======================================================
#    Standard initialization to create the plot
#    some tags are for latin-american speakers
#======================================================

 set termopt enhanced         # Allows to put ^super/_{sub} indexes
 set   autoscale              # scale axes automatically
 unset log                    # remove any log-scaling
 unset label                  # remove any previous labels
 set xtic auto                # set xtics automatically
 set ytic auto                # set ytics automatically
 set encoding iso_8859_1      # Allow to put accents 
# set grid                     # Set the type of grid

#======================================================
#     SPECIFY PLOT RANGE
#======================================================

 set xr [-22:7]
 set yr [-16:16]
#========================================================
#    KEYWORDS to control the PLOT LABELS
#========================================================
#    There are two ways to use the predertermine positions
#    or to indicate the x,y position using 
#    set key nobox at x, y

 set key nobox at -7, 10      #default inside the plot

#Para poner las leyendas en dif posiciones gnuplot utiliza
# top/bottom/center  left/right/center box/nobox
# set key center right box


#========================================================
#        PLOT INSIDE THE TOTAL CANVAS
#========================================================
#     Controls the position of the plot on the canvas
#     you can add extra "air" on the sides
#            l-> left t-> top r-> range

# set lmargin                          
# set tmargin 
# set rmargin
# set bmargin 5


#=======================================================
#   TITLES AND XY TIC LABELS
#=======================================================
#      You can modify the font and size but
#      is not necesary because you specify that on 
#      the outprint format

 set title  "TOTAL DENSITY OF STATES"
 set xlabel "Energy [eV]"
 set ylabel "Density of States [states/eV]" 

#=======================================================
#       Line Styles 
#=======================================================

 set style line 5  lt 1 lw linw pt 5  ps poin  lc rgb "navy"
 set style line 11 lt 1 lw linw pt 11 ps poin  lc rgb "red"
 set style line 10 lt 1 lw linw pt 10 ps poin  lc rgb "black" 


#======================================================
#      Add information and arrows to the plot
#======================================================

# set label "cruce evitado" at 1.3,-0.7

#Label can be "nohead"
# set arrow from 1.3,-0.7 to 1.54288,-0.897338 


#======================================================
#           Fit data to equations 
#======================================================
#    
# f1(x)= (a1*x)/(a1*x+1)
# a1=0
# fit f1(x) 'langmuir.dat' using 1:2 via a1



#======================================================
#          Output settings terminals
#=====================================================
#
#    Type of file you want to print the plot
#    eps is the most recomended 
#    Default: Shows it on your screen

set term pngcairo size 550 ,400 enhanced font "Times-New-Roman, 14"
set output "totaldos.png"


#=======================================================
#             Plot instructions
#=======================================================

#    filedatax.dat is your data file
#    using tag means which versus which column you are plotting
#    title mean the label title on the key box

 plot    "DOS0.dat" using 1:2 title 'Spin up' with lines ls 5 , \
         "DOS0.dat" using 1:3 title 'Spin down' with lines ls 11;


 unset style line
 reset